home *** CD-ROM | disk | FTP | other *** search
/ Power Programmierung / Power-Programmierung (Tewi)(1994).iso / magazine / nan_news / toolkit / outp.asm < prev    next >
Assembly Source File  |  1991-08-15  |  4KB  |  114 lines
  1. ; File......: OUTP.ASM
  2. ; Author....: Ted Means
  3. ; Date......: $Date:   15 Aug 1991 23:07:08  $
  4. ; Revision..: $Revision:   1.2  $
  5. ; Log file..: $Logfile:   E:/nanfor/src/outp.asv  $
  6. ; 
  7. ; This function is an original work by Ted Means and is placed in the
  8. ; public domain.
  9. ;
  10. ; Modification history:
  11. ; ---------------------
  12. ;
  13. ; $Log:   E:/nanfor/src/outp.asv  $
  14. ;  
  15. ;     Rev 1.2   15 Aug 1991 23:07:08   GLENN
  16. ;  Forest Belt proofread/edited/cleaned up doc
  17. ;  
  18. ;     Rev 1.1   14 Jun 1991 19:54:52   GLENN
  19. ;  Minor edit to file header
  20. ;  
  21. ;     Rev 1.0   01 Apr 1991 01:03:46   GLENN
  22. ;  Nanforum Toolkit
  23. ;  
  24.  
  25.  
  26. ;  $DOC$
  27. ;  $FUNCNAME$
  28. ;      FT_OUTP()
  29. ;  $CATEGORY$
  30. ;      DOS/BIOS
  31. ;  $ONELINER$
  32. ;      Write a byte to a specified I/O port
  33. ;  $SYNTAX$
  34. ;     FT_OUTP( <nPort>, <nValue> ) -> lResult
  35. ;  $ARGUMENTS$
  36. ;      <nPort> is the port from which to retrieve the byte.
  37. ;
  38. ;      <nValue> is the value between 0 and 255 to write to the port.
  39. ;  $RETURNS$
  40. ;     .T. if all parameters were valid and the byte was written to
  41. ;         the port.
  42. ;     .F. if invalid parameters were passed.
  43. ;  $DESCRIPTION$
  44. ;     It may sometimes be useful to write a byte to a port without having
  45. ;     to resort to C or assembler.  This function allows you to do so.
  46. ;
  47. ;     The source code is written to adhere to Turbo Assembler's IDEAL mode.
  48. ;     To use another assembler, you will need to rearrange the PROC and
  49. ;     SEGMENT directives, and also the ENDP and ENDS directives (a very
  50. ;     minor task).
  51. ;  $EXAMPLES$
  52. ;     lOk := FT_OUTP( 100, 0 )   // send a Chr(0) to port 100 (064h)
  53. ;  $SEEALSO$
  54. ;     FT_INP()
  55. ;  $END$
  56. ;
  57.  
  58.  
  59.          IDEAL
  60.  
  61. Public   FT_OUTP
  62.  
  63. Extrn    __ParInfo:Far
  64. Extrn    __ParNI:Far
  65. Extrn    __RetL:Far
  66.  
  67. Segment  _NanFor   Word      "CODE"
  68.          Assume    CS:_NanFor
  69.  
  70. Proc     FT_OUTP   Far
  71.  
  72.          Xor       AX,AX                     ; Request param count
  73.          Push      AX                        ; Put request on stack
  74.          Call      __ParInfo                 ; Get param count
  75.          Add       SP,2                      ; Realign stack
  76.          Cmp       AX,2                      ; At least two params?
  77.          JNB       GetTypes                  ; If so, continue
  78. BadParam:Xor       AX,AX                     ; Set return value to false
  79.          Jmp       Short Exit                ; Quit
  80.  
  81. GetTypes:Mov       CX,2                      ; Specify param count
  82. Top:     Push      CX                        ; Put param # on stack
  83.          Call      __ParInfo                 ; Get param type
  84.          Pop       CX                        ; Realign stack and restore CX
  85.          Test      AX,2                      ; Numeric?
  86.          JZ        BadParam                  ; No, so abort
  87.          Loop      Top                       ; Go to top of loop
  88.  
  89.          Mov       AX,1                      ; Specify first param
  90.          Push      AX                        ; Put param # on stack
  91.          Call      __ParNI                   ; Get value
  92.          Add       SP,2                      ; Realign stack
  93.          Cmp       AX,255                    ; Value valid?
  94.          JA        BadParam                  ; No, so abort
  95.          Push      AX                        ; Save value for later
  96.  
  97.          Mov       AX,2                      ; Specify first param
  98.          Push      AX                        ; Put param # on stack
  99.          Call      __ParNI                   ; Get value
  100.          Add       SP,2                      ; Realign stack
  101.          Mov       DX,AX                     ; Move port # to DX
  102.          Pop       AX                        ; Get value from stack
  103.          Out       DX,AL                     ; Write a byte to the port
  104.          Mov       AX,1                      ; Set return value to true
  105.  
  106. Exit:    Push      AX                        ; Put return value on stack
  107.          Call      __RetL                    ; Return it to Clipper app
  108.          Add       SP,2                      ; Realign stack
  109.          Ret
  110. Endp     FT_OUTP
  111. Ends     _NanFor
  112. End
  113. 
  114.